##################################################################################################################
#
# GraphRep FILE OF Industrial_Business_Process_Management_ADOxx15-v0.3.0 Application Library
#
# This File contains the GraphRep of Class 'Buffer'
#
########################## GENERAL FILE INFOS ####################################################################
#
# APPLIES Industrial Business Process Management Toolkit V:1.0
# FILE VERSION:         1.0
# AUTHOR:               NEF (BOC AM)
#
############################### File History #####################################################################
#
# [NEF, 09.11.2017]
#  - initial version for Industrial Business Process Management Toolkit V:1.0
#
##################################################################################################################

GRAPHREP #sizing:symmetrical 
AVAL type:"Type"

#if, the type of buffer is 'Dynamic' draw conveyor belt graphic
IF (type="Dynamic")
{
	
	
	FILL color:($807D61)
	RECTANGLE x:-1.2cm y:-1.13cm w:0.5cm h:0.5cm
	RECTANGLE x:-0.40cm y:-1.13cm w:0.5cm h:0.5cm
	FILL color:($DBD6A6)
	RECTANGLE x:0.7cm y:-1.13cm w:0.5cm h:0.5cm

	
	PEN w:2pt color:($454334) style:dash
	FILL color:white
	COMPOUND 2
	CURVE "t" fx:(-1.2-sin(t)/3) fy:(-0.3+cos(t)/3) from:0 to:3.14
	CURVE "t" fx:(1.2+sin(t)/3) fy:(-0.3-cos(t)/3) from:0 to:3.14

	PEN
	FILL color:($A19D7A)
	ELLIPSE x:-1.2cm y:-0.3cm rx:0.25cm ry:0.25cm
	ELLIPSE x:0.0cm y:-0.3cm rx:0.25cm ry:0.25cm
	ELLIPSE x:1.2cm y:-0.3cm rx:0.25cm ry:0.25cm
	
	ATTR "Name" y:0.3cm w:c h:c
}

#if, the type of buffer is 'Dynamic' draw batch graphic
ELSE
{
	PEN w:2pt color:($454334)
	FILL color:$FFFFFF
	COMPOUND 4
	CURVE "t" fx:(0.9+.3*sin(t)) fy:(0.9+.3*cos(t)) from:0 to:1.57
	CURVE "t" fx:(0.9+.3*sin(t)) fy:(-0.9+.3*cos(t)) from:1.57 to:3.14
	CURVE "t" fx:(-0.9+.3*sin(t)) fy:(-0.9+.3*cos(t)) from:3.14 to:4.71
	CURVE "t" fx:(-0.9+.3*sin(t)) fy:(0.9+.3*cos(t)) from:4.71 to:6.28
	FILL color:$807D61
	PEN style:null
	RECTANGLE x:-1cm y:-1cm w:.6cm h:.6cm
	RECTANGLE x:-1cm y:-.3cm w:.6cm h:.6cm
	RECTANGLE x:-1cm y:.4cm w:.6cm h:.6cm
	RECTANGLE x:-.3cm y:-1cm w:.6cm h:.6cm
	RECTANGLE x:-.3cm y:-.3cm w:.6cm h:.6cm
	RECTANGLE x:-.3cm y:.4cm w:.6cm h:.6cm
	RECTANGLE x:.4cm y:-.3cm w:.6cm h:.6cm
	RECTANGLE x:.4cm y:.4cm w:.6cm h:.6cm
	FILL color:$DBD6A6
	POLYGON 4 x1:.4cm y1:-.9cm x2:.9cm y2:-.4cm x3:1.38cm y3:-.86cm x4:.9cm y4:-1.38cm
	ATTR "Name" y:1.5cm w:c h:c
}

AVAL v:"View"

#if view is analytical, show required quantity, available quantity and capacity on buffer
IF (v = "Analytical")
{
FONT color:blue h:12pt
TEXT "Required: " y:-2.30cm w:r h:c 
ATTR "Required quantity" y:-2.30cm w:l:1.5cm h:c:12pt line-break: rigorous

AVAL rq:"Required quantity" as-original-type
AVAL aq:"Available quantity" as-original-type 
AVAL cap:"Capacity" as-original-type

SET aqc:$479439
#IF ((aq)<(rq))
#{
#SET aqc:$D1271B
#}

SET cc:$D1271B
#IF ((cap)<(rq))
#{
#SET cc:$D1271B
#}

FONT color:(aqc) h:12pt
TEXT "Available: " y:-1.9cm w:r h:c
ATTR "Available quantity"  y:-1.9cm w:l:1.5cm h:c:12pt line-break: rigorous

FONT color:(cc) h:12pt
TEXT "Capacity: " y:-1.5cm w:r h:c
ATTR "Capacity"  y:-1.5cm w:l:1.5cm h:c:12pt line-break: rigorous
}